পালস অক্সিমিটার

অক্সিজেন স্যাচুরেশন কী?
আমরা জানি অক্সিজেন ছাড়া কোনো প্রানীর পক্ষে বেঁচে থাকা সম্ভব নয়। ফুসফুসের মাধ্যমে অক্সিজেন আমাদের দেহে প্রবেশ করে এবং রক্তের মাধ্যমে সারা দেশে প্রবাহিত হয়। রক্তের হিমোগ্লোবিন অক্সিজেন পরিবহন করে। রক্তে অক্সিজেন সমৃদ্ধ হিমোগ্লোবিনের শতকরা পরিমানকে বলা হয় অক্সিজেন স্যাচুরেশন। একে SPO2 দিয়ে প্রকাশ করা হয়।



অর্থ্যাৎ,

SPO2 =(অক্সিজেন সমৃদ্ধ হিমোগ্লোবিন অনু/মোট হিমোগ্লোবিন অনু)*১০০


পালস অক্সিমিটার অক্সিজেন স্যাচুরেশন পরিমাপ করে।
এই এক্সপেরিমেন্টে আমরা আরডুইনো দিয়ে একটি পালস অক্সিমিটার তৈরী করব। পালস অক্সিমিটার তৈরী করতে সেন্সর হিসেবে আমরা ব্যবহার করেছি SparkFun Particle Sensor Breakout – MAX30105।

পার্টিকেল সেন্সরটিতে রয়েছে লাল ও সবুজ রঙয়ের দুইটি সাধারন এলইডি এবং একটি ইনফ্রারেড এলইডি। আরও আছে একটি ফোটন ডিটেক্টর। অক্সিমেট্রি মোডে পার্টিকেল সেন্সরের লাল এবং আই আর এলইডিকে জ্বালানো হয়। সেন্সরটির উপর কেউ আঙ্গুল রাখলে আঙ্গুলটি এলইডিগুলোর আলোর কিছু অংশ শোষন করে। বাকি আলোটুকু ফোটন ডিটেক্টরে পৌছায়।

অক্সিজেনসমৃদ্ধ হিমোগ্লোবিন লাল আলোর চেয়ে বেশি ইনফ্রারেড আলো শোষন করে। এবং অক্সিজেনবিহীন হিমোগ্লোবিন
ইনফ্রারেড আলোর চেয়ে বেশি লাল আলো শোষন করে। পালস অক্সিমিটার দিয়ে অক্সিজেনসমৃদ্ধ এবং অক্সিজেনবিহীন হিমোগ্লোবিন কর্তৃক শোষিত লাল এবং ইনফ্রারেড আলোর পরিমানের অনুপাত হিসাব করার মাধ্যমে রক্তের অক্সিজেন স্যাচুরেশন নির্ণয় করা হয়।

প্রয়োজনীয় যন্ত্রপাতি পরিমাণ প্রোডাক্ট লিংক
Arduino UNO-R3 1 http://bit.ly/2KhV84M
LCD module advanced 1 http://bit.ly/2W7Xwlc  
SparkFun Particle Sensor Breakout – MAX30105   1 http://bit.ly/2JluwDM  
Breadboard 1 http://bit.ly/2IjyUPg
Female to female jumper 2 http://bit.ly/2Gk1m1P  
Male to female jumper 6 http://bit.ly/2rIu6w2  
Rubber band 1  

সার্কিটঃ
প্রথমে রাবার ব্যান্ডটিকে পার্টিকেল সেন্সরের সাথে সংযুক্ত করুন।


পার্টিকেল সেন্সরটিকে ব্রেডবোর্ডে বসান।
পার্টিকেল সেন্সর ও আরডুইনো উনোর মধ্যে নিচের কানেকশনটি সম্পন্ন করুন।

Arduino UNO-R3 SparkFun Particle Sensor Breakout – MAX30105  
VCC 5V
GND GND
SDA A4
SCL A5

এলসিডি মডিউল ও আরডুইনোর মধ্যে নিচের কানেকশনটি সম্পন্ন করুন।

Arduino UNO-R3 LCD module advanced
VCC VCC
GND GND
RS 12
E 11
D4 5
D5 4
D6 3
D7 2

আমাদের পুরো সেট আপটি দেখতে ছিল এরকম-

প্রোগ্রামঃ

প্রথমে এই লাইব্রেরিটি ডাউনলোড করুন এবং ইন্সটল করুন।

তারপর নিচের প্রোগ্রামটি কম্পাইল করে আরডুইনোতে আপলোড করুন।

#include <Wire.h>
#include "MAX30105.h"
#include "spo2_algorithm.h"
#include <LiquidCrystal.h>
const int rs = 12, en = 11, d4 = 5, d5 = 4, d6 = 3, d7 = 2;
const byte RATE_SIZE = 4; //Increase this for more averaging. 4 is good.
byte rates[RATE_SIZE]; //Array of heart rates
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);
MAX30105 particleSensor;


#define MAX_BRIGHTNESS 255



#if defined(__AVR_ATmega328P__) || defined(__AVR_ATmega168__)
//Arduino Uno doesn't have enough SRAM to store 100 samples of IR led data and red led data in 32-bit format
//To solve this problem, 16-bit MSB of the sampled data will be truncated. Samples become 16-bit data.
uint16_t irBuffer[100]; //infrared LED sensor data
uint16_t redBuffer[100];  //red LED sensor data
#else
uint32_t irBuffer[100]; //infrared LED sensor data
uint32_t redBuffer[100];  //red LED sensor data
#endif

int32_t bufferLength; //data length
int32_t spo2; //SPO2 value
int8_t validSPO2; //indicator to show if the SPO2 calculation is valid
int32_t heartRate; //heart rate value
int8_t validHeartRate; //indicator to show if the heart rate calculation is valid


byte readLED = 13; //Blinks with each data read


void setup()
{
  lcd.begin(16, 2);
  lcd.print("Pulse Oximeter.");
  Serial.begin(115200); // initialize serial communication at 115200 bits per second:
  
 
  pinMode(readLED, OUTPUT);

  // Initialize sensor
  if (!particleSensor.begin(Wire, I2C_SPEED_FAST)) //Use default I2C port, 400kHz speed
  {
    Serial.println(F("MAX30105 was not found. Please check wiring/power."));
    while (1);
  }


  byte ledBrightness = 60; //Options: 0=Off to 255=50mA
  byte sampleAverage = 4; //Options: 1, 2, 4, 8, 16, 32
  byte ledMode = 2; //Options: 1 = Red only, 2 = Red + IR, 3 = Red + IR + Green
  byte sampleRate = 100; //Options: 50, 100, 200, 400, 800, 1000, 1600, 3200
  int pulseWidth = 411; //Options: 69, 118, 215, 411
  int adcRange = 4096; //Options: 2048, 4096, 8192, 16384

  particleSensor.setup(ledBrightness, sampleAverage, ledMode, sampleRate, pulseWidth, adcRange); //Configure sensor with these settings
}

void loop()
{
  bufferLength = 100; //buffer length of 100 stores 4 seconds of samples running at 25sps

  //read the first 100 samples, and determine the signal range
  for (byte i = 0 ; i < bufferLength ; i++)
  {
    while (particleSensor.available() == false) //do we have new data?
      particleSensor.check(); //Check the sensor for new data

    redBuffer[i] = particleSensor.getRed();
    irBuffer[i] = particleSensor.getIR();
    particleSensor.nextSample(); //We're finished with this sample so move to next sample


  }

  //calculate heart rate and SpO2 after first 100 samples (first 4 seconds of samples)
  maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);

  //Continuously taking samples from MAX30102.  Heart rate and SpO2 are calculated every 1 second
  while (1)
  {
    //dumping the first 25 sets of samples in the memory and shift the last 75 sets of samples to the top
    for (byte i = 25; i < 100; i++)
    {
      redBuffer[i - 25] = redBuffer[i];
      irBuffer[i - 25] = irBuffer[i];
    }

    //take 25 sets of samples before calculating the heart rate.
    for (byte i = 75; i < 100; i++)
    {
      while (particleSensor.available() == false) //do we have new data?
        particleSensor.check(); //Check the sensor for new data

      digitalWrite(readLED, !digitalRead(readLED)); //Blink onboard LED with every data read

      redBuffer[i] = particleSensor.getRed();
      irBuffer[i] = particleSensor.getIR();
      particleSensor.nextSample(); //We're finished with this sample so move to next sample

      //send samples and calculation result to terminal program through UART

      Serial.println(spo2,DEC);
      

           
     
      if(irBuffer[i]<50000)
      {
      lcd.clear();
      lcd.print("Place Finger.");
      }

      else
      {
      lcd.clear();
      lcd.setCursor(2,0);
      lcd.print("SPO2=");
      lcd.print(spo2, DEC);
      lcd.print("%");
      
     
     
      }

      
    }

    //After gathering 25 new samples recalculate HR and SP02
    maxim_heart_rate_and_oxygen_saturation(irBuffer, bufferLength, redBuffer, &spo2, &validSPO2, &heartRate, &validHeartRate);
  }
}


নিচের ছবির মতো করে রাবার ব্যান্ডটির ভেতর আঙ্গুল রাখুন।

এলসিডিতে অক্সিজেন স্যাচুরেশনের শতকরা পরিমাণ দেখুন।

Leave a Reply

This site uses Akismet to reduce spam. Learn how your comment data is processed.